PackTime

Konvertuje záznam DateTime.

Deklarace

procedure PackTime(var T: DateTime; var Time: Longint);

Režim

Windows, Reálný, Chráněný

Poznámky

Převede záznam DateTime na 4-bajtovou, pakovanou hodnotu typu Longint s datumem a časem, používanou procedurou SetFTime.

Na polích záznamu DateTime se neprovádí kontrola rozsahu.

Viz také

GetFTime

SetFTime

UnpackTime

Vzorový příklad

{GetFTime.PAS}
{Vzorový příklad pro GetFTime, PackTime, SetFTime a UnpackTime.}
{ Pro Windows: }
{ uses WinDos, WinCrt; }
uses WinDos;
 var
   f: text;
   h, m, s, hund : Word; { pro GetTime}
   ftime : Longint; { pro Get/SetFTime}
   dt : DateTime; { pro Pack/UnpackTime }
                  { pro WinDos použijte TDateTime }

 function LeadingZero(w : Word) : String;
 var
   s : String;
 begin
   Str(w:0,s);
   if Length(s) = 1 then
     s := '0' + s;
   LeadingZero := s;
 end;

 begin
   Assign(f, 'TEST.TXT');
   GetTime(h,m,s,hund);
   Rewrite(f); { Vytvoří nový soubor }
   GetFTime(f,ftime); { Dej čas }
   WriteLn('Soubor vytvořen v ',LeadingZero(h),
           ':',LeadingZero(m),':',
           LeadingZero(s));
   UnpackTime(ftime,dt);
   with dt do
     begin
       WriteLn('Časové razítko souboru je ',
               LeadingZero(hour),':',
               LeadingZero(min),':',
               LeadingZero(sec));
       hour := 0;
       min := 1;
       sec := 0;
       PackTime(dt,ftime);
       WriteLn('Nastavení časového razítka ',
               'na jednu minutu po půlnoci');
       Reset(f); { Nové otevření souboru pro čteni }
       { Jinak, zavření nastaví nový čas }
       SetFTime(f,ftime);
     end;
   Close(f);   { Zavři soubor }
 end.